import org.jetbrains.kotlin.gradle.dsl.JvmTarget

plugins {
    kotlin("jvm") version "2.2.0"
    `maven-publish` // for publishToMavenLocal
    id("org.jetbrains.dokka-javadoc") version "2.0.0"
}

group = "net.eksb"

dependencies {
    api("com.miglayout:miglayout-swing:11.4.2")
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
    }

    withSourcesJar()
}
kotlin {
    compilerOptions {
        jvmTarget.set(JvmTarget.JVM_21)
    }
}

val dokkaJavadocJar by tasks.registering(Jar::class) {
    description = "${rootProject.name} JavaDoc"
    from(tasks.dokkaGeneratePublicationJavadoc.flatMap { it.outputDirectory })
    archiveClassifier.set("javadoc")
}
tasks.build {
    dependsOn(tasks["dokkaJavadocJar"])
}

publishing {
    publications {
        create<MavenPublication>("maven") {
            from(components["java"])
            tasks["generateMetadataFileForMavenPublication"].dependsOn(dokkaJavadocJar)
            artifact(dokkaJavadocJar)
            pom {
                name = "${project.group}:${project.name}"
                description = "Kotlin utilities for Swing application"
                url = "https://git.eksb.net/stephen/kswingutil"
                licenses {
                    license {
                        name = "The Apache License, Version 2.0"
                        url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                    }
                }
                developers {
                    developer {
                        name = "Stephen Byrne"
                        email = "code@eksb.net"
                        url = "https://git.eksb.net/stephen"
                    }
                }
                scm {
                    url = "not used"
                    connection = "not used"
                    developerConnection = "not used"
                }
            }
        }
    }
}